Sub AlleDrucken()
    'Aus welchen Zellen werden die Informationen bezogen
    'Verbessert die Struktur des Excel-Makros, eigene Modifikatioen sind leichter einzupflegen
    Const z_Pfad As String = "C3"      
      'in dieser Zelle stehen die Angaben zum Pfad, an welcher Stelle die Quell Excels liegen
    Const z_Filter As String = "C4"    
      'in dieser Zelle stehen die Angaben zum Filter, welcher eine Einschränkung der betrachteten Dateien ermöglicht
    Const z_Endung As String = "C5"    
      'in dieser Zelle stehen die Angaben zur Endung der Quelldatei   

    'Konstante
    Const c_OutOrdnerName As String = "PDF"
      'Hier kann der Name eingestellt werden wie der Zielordner heißen soll + Datum und Uhrzeit

    'Variablen
    Dim v_AktuelleDatei As String      
      'Name der aktuelle Datei
    Dim v_Output As String              
      'Pfad der für die Ausgabe der PDFs zusammen gebaut wird
    Dim v_OutOrdner As String          
      'Name des neu anzulegenden Ordners (im Quellordner) für die Ausgabe 

    'Main
    Application.ScreenUpdating = False 
      'schaltet die Aktualisierung des Inhalts der Excel ab
    v_OutOrdner = "PDF_" & Format(Time, "YYYYMMDD-hhmmss") & "\"
      'ergänzt den Zielordner um das aktuelle Datum und Uhrzeit   
    MkDir (Range(z_Pfad).Value & v_OutOrdner)
      'Erstellt den Ordner für die Ausgabe im Quellverzeichnis

    v_AktuelleDatei = Dir(Range(z_Pfad).Value & Range(z_Filter).Value & Range(z_Endung).Value)
      'Gibt den ersten Dateinamen wieder, der auf die angegebenen Filterkriterien passt

    While v_AktuelleDatei <> ""
      'Eine Schleife die so lange läuft bis kein weiteres Excel mehr auf die Filterkriteren zutrifft
         OutFile = Range(z_Pfad).Value & v_OutOrdner & Replace(v_AktuelleDatei, Range(z_Endung).Value, ".pdf")
           'Pfad und Endung für die Ausgabe der Datei werden angepasst       
         Workbooks.Open Filename:=Range(z_Pfad).Value & v_AktuelleDatei, UpdateLinks:=False
           'Öffnen der zu druckenden Excel ohne den Inhalt zu aktualisieren
         ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=OutFile
           'Export der Excels als PDF. Hier wären auch alternative "Druck" bzw Export Optionen einzustellen
         ActiveWorkbook.Close savechanges:=False
           'Excel ohne zu speichern schließen
         v_AktuelleDatei = Dir
           'Übergibt den Dateinamen der nächsten Excel die auf die Filterkriterien zutrifft

   Wend

   Application.ScreenUpdating = True
      'Ab hier werden Änderungen in der Excel wieder angezeigt
End Sub

3 Gründe, warum Ihre Excel-Anwendung so kompliziert ist: mehr Informationen dazu hier.